# Temporary tools only: nix-shell dev/tools.nix. No host/profile installation.
let
  pkgs = import (builtins.fetchTarball {
    url = "https://github.com/NixOS/nixpkgs/archive/7c8764b7c7b09b34f632464276218ef9090eaa11.tar.gz";
    sha256 = "sha256-MWhktfFtFE8Jl7bf9Pkp7TR5MSdYCjCswSo0Gkb4ywc=";
  }) {};
  graphics = import (builtins.fetchTarball {
    url = "https://github.com/NixOS/nixpkgs/archive/7fd4004d0511991fff3a0524856a9be09e28c5f0.tar.gz";
    sha256 = "sha256-i5qk1kLiit98rRbh1AXmWBNT9QXC/y4l5Wk/u5EdpDQ=";
  }) {};
  qemu = (pkgs.qemu.override { hostCpuOnly = true; }).overrideAttrs (old: {
    patches = (old.patches or []) ++ [ ../patches/qemu-virtio-refresh-rate.patch ];
  });
  viewer = pkgs.virt-viewer.overrideAttrs (old: {
    src = pkgs.fetchurl {
      url = "https://releases.pagure.org/virt-viewer/virt-viewer-11.0.tar.xz";
      hash = "sha256-pD+iMlxMHHelyMmAZaww7wURohrJjlkPIjQIabrZq9A=";
    };
    patches = (old.patches or []) ++ [ ../patches/virt-viewer-hydra-session.patch ];
    doCheck = true;
  });
in pkgs.mkShell {
  nativeBuildInputs = [ pkgs.stdenv.cc pkgs.pkg-config pkgs.wayland-scanner ];
  buildInputs = [ pkgs.wayland.dev pkgs.libxkbcommon.dev ];
  packages = [ pkgs.python3 qemu viewer graphics.labwc pkgs.foot
               pkgs.brightnessctl pkgs.wayland-utils pkgs.wlr-randr ];
  passthru = { inherit viewer qemu; labwc = graphics.labwc; };
}